// OUTDOOR SECTION SCRIPT
//    Section: X = 0, Y = 0

// This is the special encounter script for this town.
// The states INIT_STATE and START_STATE have
// meanings that are described in the documenation. States you write
// yourself should be numbered from 10-100.

beginoutdoorscript;

variables;

short i,j,k,r1,choice;

body;

beginstate INIT_STATE;
	set_state_continue(18);
break;

beginstate START_STATE;
	set_state_continue(18);
break;

beginstate 10;
	message_dialog("The passages between the rocks become too difficult for you to navigate.","");
	block_entry(1);
	print_str("Blocked.");
break;

beginstate 13;
	if (get_flag(200,3) == 250)
		end();
	reset_dialog();
	add_dialog_str(0,"A small freshwater pool is the source of a clean drink for many of the nearby wildlife. Unfortunately for you, some of the wildlife also feels threatened with your presence. The more bold attack you outright.",0);
	add_dialog_str(1,"These are no normal wildlife, however. Flawless in equine form, a single, menacing horn protrudes from each forehead. From the stains of dried blood on some of these horns, these are not simply for show.",0);
	add_dialog_choice(0,"OK.");
	choice = run_dialog(1);
	set_flag(200,3,250);
	create_out_spec_enc(0);
break;

beginstate 15;
	reset_dialog();
	add_dialog_str(0,"Set up in the middle of the plains is a small encampment of snakeskin hunters. Knowing you for adventurers, they call you over to have a look at their wares.",0);
	add_dialog_str(1,"Most of the decorative skins aren't too useful to you.  But they regularly find Healing Herbs during their forays.",0);
	add_dialog_choice(0,"OK.");
	add_dialog_choice(1,"Buy.");
	choice = run_dialog(1);
	if (choice == 2)
		begin_shop_mode("Herb Camp","You find some useful herbs that are going cheap.",5,1,-1);
break;

beginstate 17;
	if (get_flag(200,4) == 250)
		end();
	set_flag(200,4,250);
	message_dialog("The western coastlands are known to be ravaged constantly by the pirates of Skane. True to the rumors, you meet up with a group of them presently.",
	  "This group doesn't care at all about who you are. They're just after your valuables. Consequentially, the discussion is short and pointed.");
	create_out_spec_enc(1);
break;

beginstate 18;
	if (get_flag(200,3) == 250)
		set_terrain(31,14,0);
	if (get_flag(200,4) == 250)
	  set_terrain(25,38,0);
break;

